# -*-s2-*-
layerinfo "type" = "layout";
layerinfo "name" = "Parrhesia";
layerinfo "lang" = "en";
layerinfo "author" = "Sam Angove";
layerinfo "author_email" = "samATrephraseFULLSTOPnet";
layerinfo "is_public" = 1;
layerinfo "source_viewable" = 1;

# v. 1.0 - 2006.01.31 #

# A long, long time ago, back when S2 was new and promising, this style was
# based on <lj user="mart">'s "A Sturdy Gesture". 
#
# I don't think there's much/any code from it left over, but it (and other
# system styles) were ripped off^H^H^H^H^H^H^H^H^H^Hconsulted. 
# Blah blah blah GPL Free Software etc. etc.
#
# A bunch of things aren't supported, because this isn't a system style 
# and it's a lot of work. There's some hard-coded English in there, for 
# example. 
#
# Friend colours aren't there because it's a *huge* pain to write a style 
# with dynamic colours -- borders, underlines, headings &c. have to change
# shades to match the simple foreground and background picked. 
# Colour properties aren't supported because making them simple requires
# just as much bother with dynamic colouring, and if they're complex then
# it's easier for people to just edit the CSS.

propgroup CSS {
	property string external_css_url {
		des = "URL to external stylesheet.";
	}
		
	property string custom_css { 
		des = "CSS rules to append to theme stylesheet.";
		rows = 20;
		cols = 40;
	}
}

propgroup Sidebar {
	property string custom_sidebar { 
		des = "HTML appended to the bottom of the sidebar. (RecentPage only.)";
		rows = 20;
		cols = 40;
	}
	
	property string sidebar_footer { 
		des = "The footer is appended to the sidebar.";
		rows = 20;
		cols = 40;
	}	

}

propgroup Text {
	property use text_permalink;
	property use text_post_comment;
	property use text_post_comment_friends;
	property use text_read_comments;
	property use text_nosubject;		
	property use text_poster_anonymous;
	property use text_meta_mood;	
	property use text_meta_music;
	property use text_day_next;
	property use text_day_prev;
	property use text_skiplinks_back;
	property use text_skiplinks_forward;
	property use text_view_archive;
	property use text_view_recent;	
	property use text_view_friends;
	property use text_view_month;
	property use text_view_userinfo;
	
		set text_permalink = "#";
		set text_post_comment = "reply";
		set text_post_comment_friends = "reply";
		set text_nosubject = "(no subject)";
		set text_poster_anonymous = "(anonymous)";
		
	property string text_error {
		des = "Error page header";
	}
		set text_error = "Error";
}

propgroup misc {
	
	property string custom_favicon { 
		des = "URL of custom favicon.";
		example = "http://example.com/favicon.ico";
		}
		set custom_favicon = "";
	
	property use page_recent_items;	
		set page_recent_items = 10;	
	
	property use page_friends_items;	
		set page_friends_items = 50;	

	property int friendspage_expanded_limit { des = "Show how many FriendsPage entries if all are expanded?"; }
		set friendspage_expanded_limit = 20;

}

# These noui properties are just global variables.
property int expanded_count { noui = 1; }
	set expanded_count = 0;	
property string lastfeed { noui = 1; }
	set lastfeed = "";
property bool collapsed { noui = 1; }
	set collapsed = false;
property int itemsonpage { noui = 1; }
	set itemsonpage = 0;

set tags_aware = true;

# string replace function and rehtmlizerer
# from: http://www.livejournal.com/community/lj_style/317854.html?thread=1504670#t1504670
#
function replacetext(string text, string find, string replacement) : string {
  var string[] findarray;
  var int pos = 1;
  foreach var string findcharacter($find) {
    $findarray[$pos] = $findcharacter;
    $pos = $pos+1;
  }
  var int place = 1;
  var bool found = false;
  var string completedtext = "";
  var string foundtext = "";
  foreach var string searchcharacter($text) {
    if  ($searchcharacter == $findarray[$place]) {
      if ($place == $find->length()) {
        $foundtext =  $replacement;
        $place = 1;
      } else {
        $foundtext = $foundtext + $searchcharacter;
        $place = $place + 1;
      }	
    } else {
      $completedtext = $completedtext + $foundtext + $searchcharacter;
      $foundtext = "";	
      $place = 1;		
    }
  }
  $completedtext = $completedtext + $foundtext;
  return $completedtext;
}

function rehtml(string text) : string {
  return replacetext( replacetext( replacetext($text , "&gt;", ">") , "&lt;", "<"), "&amp;", "&");
}

# override me in themes
function print_footer() {
	if ($*sidebar_footer != "") {
		print rehtml(replacetext($*sidebar_footer, "<br/>", ""));
	}
}

function print_tags(Entry e) : string {
	var string tags;
	var string tag;
	
	if ($e.tags) {
		var int tcount = 0;

		foreach var Tag t ($e.tags) {
			$tcount++;
			
			$tag = """<a rel="tag" href="$t.url">$t.name</a>""";
			$tags = $tags+$tag;
			if ($tcount != size $e.tags) { $tags = $tags+", "; }
		}

	} 
	
	return $tags;

}

# 
function print_linklist(UserLink[] linklist) {
	println "<ul>";
	foreach var UserLink l ($linklist) {
		if (not $l.is_heading) {
			"""
			<li><a href="$l.url">$l.title</a></li>
			""";
		} else {
			"""
			<li><span class="userlink-heading">$l.title</span>
				"""; 
				print_linklist($l.children); 
				"""
			</li>
			""";
		}
	}
	println "</ul>";
}

# Converts an associative array to an argument list, 
# i.e. {"page" => "somevar", "id" => "othervar"} to
# "?page=somevar&id=othervar"
#
function array_to_args(string{} items) : string {
	var string args;
	var bool q = false;
	
	foreach var string key ($items) {
		if ($key != "") {
			if (not $q) {
				$args = "?";
				$q = true;
			} else {
				$args = $args+"&amp;";
			}
			$args = $args+"$key="+$items{"$key"};
		}
	}
	return $args;
}

# 
# Default stylesheet. Override this function in themes, et voila!
#
function lay_stylesheet() {

"""
body {
	font: 11px/16px Verdana, Arial, sans-serif;
	color: #000;
	background: #fff;
	margin: 0;
	padding: 0;
}

a { text-decoration: none; }
a:link { color: #69f;}
a:visited { color: #36c; }
a:hover { color:#9cf; }
a:active { color: #9cf; }

img { border: 0; }

h1 {
	font: bold 2em/1em Verdana, Times New Roman, serif;
	color: #fff;
	margin: 0 0.3em 0.3em 0.3em;
	border-bottom: 1px solid #fff;
}

h2 {
	font: bold 1em Georgia, Times New Roman, serif;
}

h2 a, h2 a:link, h2 a:hover, h2 a:active, h2 a:visited {
	color: #000;
	text-decoration: none;
}

#central {
	padding: 0;
	margin: 0;
	text-align: justify;
	position: absolute;
	left: 18em;
	top: 0;
	width: 52em;
}

#comment-central {
	margin: 0;
	padding: 0;
}

#side {
	position: absolute;
	left: 2.5em;
	top: 0;
	width: 15em;
}

#side ul {
	list-style-type: none;
	margin: 0;
	padding: 0;
}

#side li {
	margin: 0;
	padding: 0;
}

.sidebox {
	margin-top: 0.2em;
	padding: 0.5em 0.8em;
	background: #fff;
	color: #333;
}
.sidebox .title {
	color: #333;
	margin-bottom: 0.3em;
	border-bottom: 0.1em solid #999;
	text-align: center;
	text-transform: uppercase;
}

#sidebox-title {
	background: #6af;
	color: #fff;
	padding: 0.9em;
	text-align: center;
}

#sidebox-nav {
	background: #eee;
}

#sidebox-expand, #sidebox-months, #sidebox-years, #sidebox-links, #sidebox-tools {
	background: #ddd;
}

#sidebox-login {
	background: #fff;
	border: 2px dotted #ccc;
}

#sidebox-tags {
	background: #ccc;
}

#sidebox-types {
	text-align: center;
	background: #aaa;
}
#sidebox-tools {
	text-align: center;
}



.box {
	margin: 1em 5em 0 0; 
	background-color: transparent;
}


.entry {
	background-color: transparent;
	padding: 1em;
}
.entry-title {
	font: normal 2em "Georgia", "Times New Roman", Times New Roman, serif;
	color: #333;
	border-bottom: 2px solid #ddd;
}
.entry-title a {
	text-decoration: none;
	color: #000;
}

.entry-links {
	width: 100%;
	color: #000;
	text-decoration: none;
	text-align: left;
}

.entry-meta {
	text-align: right;
	font-size: 0.9em;
	margin-top: 1em;
	padding: 1em;
}

.entry-datetime {
	color: #999;
}
.entry-header {
	text-align: left;
	font-weight: bold;
	background-color: transparent;
	color: black;
	padding-left: 1em;
	padding-bottom: 0;
}


/* Collapsed/small items on FriendsPage, MonthPage, TagsPage, YearPage... */

.c-item {
	width: 57.5em;
	margin: 0.5em 5em 0 2em;
	height: 1.6em;
}
.c-item a { color: #333; }

.c-header {
	margin: 0.5em;
	font-size: 1em;
}

.c-expand {
	width: 1em;
	padding: 0.2em;
}
.c-title {
	width: 40em;
	padding: 0.2em;
}
.c-poster {
	width: 14em;
	text-align: right;
	padding: 0.2em;
	text-align: right;
}
.c-count {
	color: #aaa;
	text-align: right;
	padding: 0 0 0.5em 0.5em;
	font-size: 0.8em;
}
.c-security {
	text-align: center;
}


.poster {
	padding-left: 1em;
	padding-right: 1em;
	height: 2.5em;
	font-weight: normal;
}

.ljuser {
	text-decoration: none;
	font-weight: bold;
	white-space: nowrap;
}
.ljuser img {
	vertical-align: bottom;
}


.commentqr {
	background: #ccc;
	border: 1px solid #ddd;
}

input[type="text"], textarea {
	border: 1px solid #333;
	background: #eee;
}
.replyform {
	background: #ccc;
	border: 1px solid #333;
	padding: 5px;
}
textarea.textbox {
	width: 35em;
}

.metaitem {
	margin: 0;
}
.metaitemlabel {
	font-weight: bold;
}






.commentspacer {
	margin-left: 2.5em;
}
.comment {
	margin: 0.5em;
	width: 50em;
	background: #fff;
	border-bottom: 0.2em solid #ccc;
}
.comment-top {
	border-bottom: 0.2em solid #ccc;
	padding: 0.2em;
	background-color: #eee;
}
.comment-datetime {
	float: right;
	text-align: center;
	color: #666;
	font-weight: normal;
}


.comment-tools {
	text-align: right;
}

.commentnaked {
	text-align: center;
	padding: 0.3em;
}
.commenttalklinks {
	text-align: center;
	font-size: 1em;
}
.commententry {
	padding: 1em;
}
.collapsedcomments {
	margin-top: 0.5em;
	margin-bottom: 0.5em;
	clear: both;
}
.replybox {
	margin-left: 2.5em;
	border: 0.1em solid #666;
}



/* yp: yearpage; yw: yearweek */

.yp-month td {
	width: 3em;
	height: 3em;
	padding: 0.2em;
	font-size: 2em;
}

.yp-month {
	text-align: center;
}

.yw-day-blank {
	background: #fff;
}

.yw-day-full {
	background: #eee;
}
.ymd {
	float: right;
	font-size: 0.6em;
	margin-top: -1.5em;
	color: #999;
}


""";
}


function print_stylesheet() {
	
	# override CSS in themes without breaking custom_css property
	lay_stylesheet();

	if ($*custom_css != "") {
		print replacetext($*custom_css, "<br/>", "");
	}
}

# ::lay_build_url()
# returns the current url plus arguments, sort of
#
function Page::lay_build_url(string{} items) : string {
	return $.base_url + array_to_args($items);
}
function RecentPage::lay_build_url(string{} items) : string {
	if ($.nav.skip != 0) { 
		$items{"skip"} = string($.nav.skip); 
	} 
	return $.base_url + array_to_args($items);
}
function FriendsPage::lay_build_url(string{} items) : string {
	var string url = $.base_url;
	
	if ($.friends_mode != "") {
		$url = $url + "/$.friends_mode";
	} else {
		$url = $url + "/friends";
	}
	
	if ($.filter_active) {
		$url = $url + "/$.filter_name";
	}

	if ($.nav.skip != 0) {
		$items{"skip"} = string($.nav.skip);
	} 
	
	return $url + array_to_args($items);
}
function TagsPage::lay_build_url(string{} items) : string {
	return $.base_url + "/tag/" + array_to_args($items);
}
function YearPage::lay_build_url(string{} items) : string {
	foreach var YearYear y ($.years) {
		if ($y.displayed) {
			return $y.url+array_to_args($items);
		}
	}
	return $.base_url;
}


function Page::lay_page_nav() { }
function RecentPage::lay_page_nav() {
		
	if ($.nav.backward_url == "" and $.nav.forward_url == "") {
		return;
	}
	if ($.nav.backward_url != "") {
		var string previous = get_plural_phrase($.nav.backward_count, "text_skiplinks_back");
		println """<li><a href="$.nav.backward_url">$previous</a></li>""";
	}
	if ($.nav.forward_url != "") {
		var string next = get_plural_phrase($.nav.backward_count, "text_skiplinks_forward");
		println """<li><a href="$.nav.forward_url">$next</a></li>""";
	}
	
}

function Page::title() : string {
	var string title = $this.global_title;
	var string view = $this->view_title();
	
	return """$title : $view""";
}

function Page::lay_print_error(string message) {
	"""
	<div class="error">
	<h2 class="error-header">$*text_error</h2>
	<p>$message</p>
	</div>
	""";
}

function Page::lay_collapsed_entry(Entry e) {
	$*collapsed = true;
	
	var string name = $.args{"name"};
	var string subject = ($e.subject != "" ? $e.subject : $*text_nosubject);
	var string count = "";
	
	println """<tr class="c-item">""";
	
	if ($.view != "month") { 
		println """<td class="c-expand"><a href='"""+$this->lay_build_url({".id" => string($e.itemid)})+"""#entry-$e.itemid'>+</a></td>"""; 
	}	
	
	println """<td class="c-title"><a href="$e.permalink_url">$subject</a></td>"""; 	
	
	if (not $e.comments.enabled) {
		$count = "-";
	} elseif ($e.comments.count > 0) {
		$count = string($e.comments.count);
	}
	
	println """<td class="c-count">$count</td>""";
	
	if ($.view == "friends" or $e.poster.username != $.journal.username) {
		"""<td class="c-poster">""";
		if ($e.journal.username != $*lastfeed) {
			$this->print_entry_poster($e);
		}
		$*lastfeed = $e.journal.username;
		"""</td>""";
	}
	
		
	if ($e.security != "") {
		println """<td class="c-security"><img src="$e.security_icon.url" alt="[$e.security]" /></td>""";
	}
	
	println """</tr>""";
}


function Entry::print_metadata() {
	var string caption;
	var string val;
	var Image i;
	
	if (size $.metadata == 0) { return; }
		foreach var string k ($.metadata) {
		$caption = $k;
		$val = $.metadata{$k};
		if ($k == "music") {
			$caption = $*text_meta_music;
		} elseif ($k == "mood") {
			$caption = $*text_meta_mood;
			if (defined $.mood_icon) {
				$i = $.mood_icon;
				$val = $i->as_string("'$.metadata{$k}'")+" "+$val;
			}
		}
		println """<div class="metaitem"><span class="metaitemlabel">$caption:</span> $val</div>""";
	}
}



function Page::lay_entry(Entry e) {
   	$*collapsed = false;
	
	# $e.dom_id isn't populated (yet?)
	var string dom_id = ($e.dom_id != "") ? $e.dom_id : "e-$e.itemid";
	
	var string datetime = $e.time->date_format("%%HH%%:%%min%%, %%dd%%/%%mm%%/%%yyyy%%");
	var string subject = ($e.subject != "" ? $e.subject : $*text_nosubject);
	
	
	"""
	<div class="box" id="$dom_id">
		<div class="entry-header">
			<h2 id="entry-$e.itemid" class="entry-title">$subject</h2>
		</div>
		
		<div class="poster">
	""";
	
	if ($this.view == "friends" or $e.poster.username != $this.journal.username) {
		$this->print_entry_poster($e);
	}
	if ($e.security != "") {
		print """<img src="$e.security_icon.url" alt="[$e.security]" />""";
	}
	
	"""
		</div>
   		<div class="entry">
   	""";
   		
   		$e->print_text();
   	
   	"""
   		</div>
		<div class="entry-meta">
	""";
	
	 	var string tags;
		var string tag;
		
		if ($e.tags) {
			var int tcount = 0;
	
			foreach var Tag t ($e.tags) {
				$tcount++;
				
				$tag = """<a rel="tag" href="$t.url">$t.name</a>""";
				$tags = $tags + $tag;
				if ($tcount != size $e.tags) { $tags = $tags+", "; }
			}
			"""<div class="metaitem"><span class="metaitemlabel">Tags:</span> $tags</div>""";
		} 
		
	
		$e->print_metadata();
		"""
			<div class="entry-links">
				<span class="entry-datetime">$datetime</span> | <a href="$e.permalink_url">$*text_permalink</a> - 
		""";
			$e.comments->print();
		
		"""
			</div>
		</div>
	</div>
	""";
   	
   	if ($this.view == "recent" or $this.view == "friends") {
		"""	<div class="section"></div>""";
	}
	
}


function Page::print_entry(Entry e) {
	$this->lay_entry($e);
}



function FriendsPage::print_entry(Entry e) {
	var Friend f = $.friends{$e.journal.username};
	var bool using_tag = false;
	

	foreach var Tag t ($e.tags) {
		if ($this.args{"tag"} == $t.name) {
			$using_tag = true;
		}
	}
	
	if ($this.args{"name"} == "all") {
		$*expanded_count++;
		if ($*expanded_count > $*friendspage_expanded_limit) {
			return;
		}
	}

	if ($e.new_day) {
		"""
		<tr class="item">
			<td colspan="4"><h2 class="c-header">"""+$e.time->date_format($*lang_fmt_date_long)+"""</h2></td>
		</tr>
		""";
	}	
	if (($this.args{"name"} == "all") or ($using_tag == true) or ($this.args{"name"} == $e.journal.username) or (int($this.args{"id"}) == $e.itemid) or ($.args{"when"} == string($e.time.year)+zeropad($e.time.month, 2)+zeropad($e.time.day, 2))) {
		"""</table>""";
		$this->lay_entry($e);
		"""<table class="central-table">""";
	} else {
		$this->lay_collapsed_entry($e);
	}
}


function Page::print_entry_poster(Entry e) {
	var string poster = $e.journal->as_string();
	
	if (not $e.poster->equals($e.journal) and not $*collapsed) {
		$poster = $e.poster->as_string()+" in "+$poster;
	}
	print $poster;
}

#######
# SIDE BOXES
# #  #    #        #                #

# For paid user override in theme layers
function lay_user_boxes() : void { }

function Page::lay_subtitle() : string {
	if ($.global_subtitle != "") {
		return "$this.global_subtitle, "+$this->view_title();
	} else {
		return $this->view_title();
	}
}

function Page::lay_title_box() : void {
	"""
	<div class="sidebox" id="sidebox-title">
		<h1>"""+rehtml($this.global_title)+"""</h1>
		<p>"""+rehtml($this->lay_subtitle())+"""</p>
	</div>
	""";
}

function Page::lay_nav_box() : void {
	"""
	<div class="sidebox" id="sidebox-nav">
		<div class="title">Navigation</div>
		<ul>
	""";	
	
	$this->lay_page_nav();
	foreach var string v ($.views_order) {
		if ($.view == $v) {
			println """<li id="currentpage">"""+lang_viewname($v)+"""</li>""";
		} else {
			println """<li><a href="$.view_url{$v}">"""+lang_viewname($v)+"""</a></li>""";
		}
	}
	
	"""
		</ul>
	</div>
	""";
}

function Page::lay_login_box() {
	if (not viewer_logged_in()) {
	"""
	<div class="sidebox" id="sidebox-login">
		<div class="title" id="sidebox-login-title">Log In</div>
		<p><a href="$*SITEROOT/login.bml" title="Log in.">Log in</a> to see protected and friends-only entries.</p>
	</div>
	""";
	}
}

function Page::lay_link_box() {
	if (size $.linklist < 1) { return; }
	
	"""
	<div class="sidebox" id="sidebox-links">
		<div class="title" id="sidebox-links-title">Links</div>
		<ul>
	""";
	
	print_linklist($.linklist);
	
	"""
		</ul>
	</div>
	""";
}

function MonthPage::lay_months_box() : void {
	if (size $.months == 0) { return; }
	
	"""
	<div class="sidebox" id="sidebox-months">
		<div class="title">$.date.year</div>
		<ul>
	""";	
	
	foreach var MonthEntryInfo m ($.months) {
		if ($.date.year == $m.date.year) {
			println """<li><a href="$m.url">"""+$m.date->date_format("%%month%%")+"</a></li>";
		}
	}
	
	"""
		</ul>
	</div>
	""";
}

function DayPage::lay_day_box() {
	"""
	<div class="sidebox" id="sidebox-days">
		<div class="title">Days</div>
		<ul>
	""";	
	
	"""<li><a href="$.prev_url">"""+$.prev_date->date_format("%%day%%")+" "+lang_ordinal($.prev_date.day)+"""</a></li>""";
	"""<li><a href="$.next_url">"""+$.next_date->date_format("%%day%%")+" "+lang_ordinal($.next_date.day)+"""</a></li>""";
	
	"""
		</ul>
	</div>
	""";

}

function RecentPage::lay_tag_box() : bool {
	
	var int{} feed_itemcount;
	var int{} feed_tagcount;
	var int num_entries = size $.entries;
	var bool is_tagpage = false;
	
  	foreach var Entry e ($.entries) {
		$feed_itemcount{"$e.journal.username"} = $feed_itemcount{"$e.journal.username"} + 1; 
  		$*itemsonpage = $*itemsonpage + 1;
  		foreach var Tag t ($e.tags) {
			$feed_tagcount{"$t.name"} = $feed_tagcount{"$t.name"} + 1;
			
			# If the same tag is on every entry, we're going to assume
			# it's the archive for that tag. Dodgy, dodgy...
			# Awaiting resolution of <http://zilla.livejournal.org/show_bug.cgi?id=2309>
			if ($feed_tagcount{"$t.name"} == $num_entries) {
				$is_tagpage = true;
			}
		}
  	}
	
	if (not $is_tagpage) { 
		return false; 
	}
	
	"""
	<div class="sidebox" id="sidebox-tags">
		<div class="title" id="sidebox-tags-title">Tags</div>
   		<ul>
	""";
	
	foreach var TagDetail tag ($this->visible_tag_list()) {
		if ($tag.use_count > 1) { """<li><a href="$tag.url">$tag.name</a> ($tag.use_count)</li>"""; }
	
	}
	"""
		</ul>
	</div>
	""";
	return true;
}


function EntryPage::lay_tool_box() {
	var string text;

	"""
	<div class="sidebox" id="sidebox-tools">
		<div class="title" id="sidebox-tools-title">Entry</div>
	""";
	$.entry->print_linkbar();
	"""
	</div>
	""";
}




function YearPage::lay_years_box() {
	var string year;
	
	if (size $.years < 2) { return; }
	
	"""
	<div class="sidebox" id="sidebox-years">
		<div class="title" id="sidebox-years-title">Years</div>
   		<ul>
	""";
	foreach var YearYear y ($.years) {
		if ($y.displayed) {
			$year = string($y.year);
		} else {
			$year = """<a href="$y.url">$y.year</a>""";	
		}
		println """<li>$year</li>""";
	}
	
	"""
		</ul>
	</div>
	""";

}

function FriendsPage::lay_expand_boxes() {

	var int{} feed_itemcount;
	var int{} feed_tagcount;
	var int num_entries = size $.entries;
	var int expanded_items = ($*friendspage_expanded_limit <= $num_entries) ? $*friendspage_expanded_limit : $num_entries;
	var bool is_tagpage = false;
	
  	foreach var Entry e ($.entries) {
		$feed_itemcount{"$e.journal.username"} = $feed_itemcount{"$e.journal.username"} + 1; 
  		$*itemsonpage = $*itemsonpage + 1;
  		foreach var Tag t ($e.tags) {
			$feed_tagcount{"$t.name"} = $feed_tagcount{"$t.name"} + 1;
			
			# If the same tag is on every entry, we're going to assume
			# it's the archive for that tag. Dodgy, dodgy...
			if ($feed_tagcount{"$t.name"} == $num_entries) {
				$is_tagpage = true;
			}
		}
  	}


	"""
		<div class="sidebox" id="sidebox-expand">
			<div class="title" id="sidebox-expand-title">Expand</div>
			<ul>
			<li><a href='"""+$this->lay_build_url({""=>""})+"""'>unfiltered</a> ($*itemsonpage)</li>
			<li><a href='"""+$this->lay_build_url({".name" => "all"})+"""'>expanded</a> ($*friendspage_expanded_limit)</li>
	""";

	foreach var string feedkey ($feed_itemcount) {
		"""
			<li><a href='"""+$this->lay_build_url({".name" => $feedkey})+"""'>$feedkey</a> ($feed_itemcount{"$feedkey"})</li>
		""";
	}
  
  	"""
			</ul>
  		</div>
  	"""; 
	
	if (size $feed_tagcount > 0) { 
	
	"""	
 		<div class="sidebox" id="sidebox-tags">
 			<div class="title">Tags</div>
  			<ul>	
	"""; 
	
		foreach var string tagkey($feed_tagcount) {
			"""<li><a href='"""+$this->lay_build_url({".tag" => $tagkey})+"""'>$tagkey</a> ($feed_tagcount{"$tagkey"})</li>""";
		} 
		
	"""
			</ul>
  		</div>
	"""; 
	
	} 
	
	  
	"""  
  		<div class="sidebox" id="sidebox-types">
  			<div class="title">Filter by Type</div>
   			<a href='"""+$this->lay_build_url({""=>""})+"""'>All</a>
		   	<a href='"""+$this->lay_build_url({"show" => "p"})+"""'><img src="$*IMGDIR/userinfo.gif" alt="community" /></a>
		   	<a href='"""+$this->lay_build_url({"show" => "c"})+"""'><img src="$*IMGDIR/community.gif" alt="community" /></a>
		   	<a href='"""+$this->lay_build_url({"show" => "y"})+"""'><img src="$*IMGDIR/syndicated.gif" alt="syndicated" /></a>
   		</div>
   	""";

}

function Page::lay_side_boxes() {
	$this->lay_title_box();
	$this->lay_login_box();
	$this->lay_nav_box();
}
function MonthPage::lay_side_boxes() {
	$this->lay_title_box();
	$this->lay_login_box();
	$this->lay_nav_box();
	$this->lay_months_box();
}
function DayPage::lay_side_boxes() {
	$this->lay_title_box();
	$this->lay_login_box();
	$this->lay_nav_box();
	$this->lay_day_box();
}
function RecentPage::lay_side_boxes() {
	$this->lay_title_box();
	$this->lay_login_box();
	$this->lay_nav_box();
	if (not $this->lay_tag_box()) {
		$this->lay_link_box();
		lay_user_boxes();
	}
	if ($*custom_sidebar != "") {
		print rehtml(replacetext($*custom_sidebar, "<br/>", ""));
	}
}
function FriendsPage::lay_side_boxes() {
	$this->lay_title_box();
	$this->lay_login_box();
	$this->lay_nav_box();
	$this->lay_expand_boxes();

}
function EntryPage::lay_side_boxes() {
	$this->lay_title_box();
	$this->lay_nav_box();
	$this->lay_tool_box();
}
function YearPage::lay_side_boxes() {
	$this->lay_title_box();
	$this->lay_nav_box();
	$this->lay_years_box();
}


function RecentPage::print_body() {
	
	if (size $.entries == 0) {
		$this->lay_print_error($*text_noentries_recent);
	} else {
		foreach var Entry e ($.entries) {
			$this->print_entry($e);
		}
	}
}

function FriendsPage::print_body() {
	 
	if (size $.entries == 0) {
		$this->lay_print_error($*text_noentries_recent);
	} else {
		println "<table class='central-table'>";
		foreach var Entry e ($.entries) {
			$this->print_entry($e);
		}
		println "</table>";
	}
}


# tag list output -- using heatmap instead
#function TagsPage::print_body() {
#	var string sort = ($.args{"sort"} == "" or $.args{"sort"} == "ascending") ? "descending" : "ascending";
#	
#	"""
#	<table class="central-table">
#		<tr class="c-item">
#			<th><a href='"""+$this->lay_build_url({".sort" => "$sort"})+"""'>tag</a></th>
#			<th>count</th>
#		</tr>
#	""";
#	
#	if ($.args{"sort"} == "descending") {
#		$.tags = reverse $.tags;
#	} 
#	
#	foreach var TagDetail tag ($.tags) {
#		"""
#		<tr class="c-item">
#			<td class="c-title"><a href="$tag.url">$tag.name</a></td>
#			<td class="c-count">$tag.use_count</td>
#		</tr>
#		""";
#	}
#	
#	"""</table>""";
#
#}


# tag heatmap output
function TagsPage::print_body() {
	var string sort = ($.args{"sort"} == "" or $.args{"sort"} == "ascending") ? "descending" : "ascending";
	
	var int highest = 0;
	var int lowest = 99999999;
	var int countspread;
	
	var int fontmin = 10;
	var int fontmax = 100;
	var int fontspread = $fontmax - $fontmin;
	
	
	var int fontstep = 0;
	var int fontsize;
	var string font;

	foreach var TagDetail tag ($.tags) {
		if ($tag.use_count > $highest) {
			$highest = $tag.use_count;
		}
		if ($tag.use_count < $lowest) {
			$lowest = $tag.use_count;
		}
	}
	
	$countspread = $highest - $lowest;
	
	if ($countspread > 0) {
		$fontstep = $fontspread/$countspread;
	}
	
	foreach var TagDetail tag ($.tags) {
		if ($highest == $lowest) {
			$font = string($fontmin) + "px";
		} else {
			$fontsize = $fontmin + (($tag.use_count - $lowest) * $fontstep);
			$font = string($fontsize) + "px";
		}
		
		"""<a href="$tag.url" style="font-size: $font;">$tag.name</a> """;
	}
		

}


function CommentInfo::print() {
	if ($.enabled) {
		if ($.count > 0 or $.screened) {
			$this->print_readlink();
		}
		" (";
		
		$this->print_postlink();
		")";
	}
}





function DayPage::print_body() {
	
	if (not $.has_entries) {
		$this->lay_print_error($*text_noentries_day);
	} else {
		foreach var Entry e ($.entries) {
			$this->print_entry($e);
		}
	}

}

function Page::lay_entrylite(EntryLite e, string title) {
	
	var string datetime = $e.time->date_format("%%HH%%:%%min%%, %%dd%%/%%mm%%/%%yyyy%%");
	var string subject = ($e.subject != "" ? $e.subject : $*text_nosubject);
	var string box_id;
	if ($e.dom_id != "") {
		$box_id = """id='$e.dom_id'""";
	}
	
	"""
	<div class="box"$box_id>
		<div class="entry-header">
			"""; if ($title != "") { println "<p>$title</p>"; } """
			<h2 class="entry-title">$subject</h2>
		</div>
		
		<div class="poster">"""; print $e.poster->as_string(); """</div>
   		
   		<div class="entry">"""; $e->print_text(); """</div>
		
		<div class="entry-meta">
			
			<div class="entry-links">
				<span class="entry-datetime">$datetime</span> | <a href="$e.permalink_url">$*text_permalink</a>
			</div>
		</div>
	</div>
	""";

}

function EntryPage::print_body() {
	
	if ($.viewing_thread) {
		"""	
		<div class="box">
		<div class="entry-header">
			<h2 class="entry-title">Viewing a comment on &lsquo;<a href="$this.entry.permalink_url">$this.entry.subject</a>&rsquo;</h2>
		</div>
		</div>
		""";
	} else {
		$this->print_entry($.entry);
	}
	
	"""<div id="comment-central">""";
	
	if ($.entry.comments.enabled) {
		if ($.multiform_on) {
			$this->print_multiform_start();	
		}
		if ($.entry.comments.count > 0) {
			"""
			<div class="commentnaked">
			""";
			var ItemRange range = $.comment_pages;
			
			if (not $range.all_subitems_displayed) {
				if ($range.url_last != "") {
					"""<a href="$range.url_first">&larr;</a>""";
				}
				foreach var int page (1 .. $range.total) {
					if ($range.current != $page) {
						""" [<a href='"""+$range->url_of($page)+"""'>$page</a>]""";
					} else {
						""" [$page]""";
					}
				}
				if ($range.url_next != "") {
					""" <a href="$range.url_first">&rarr;</a>""";
				}
			}
			
			"""
			</div>
			""";
		}
		$this->print_comments($.comments);
		
		if ($.multiform_on) {
			"""
			<div id="multiform">
			""";
			$this->print_multiform_actionline();
			$this->print_multiform_end();	
			"""
			</div>
			""";
		}
		
	}
	"""
		</div>
	""";
	
}

function ReplyPage::print_body() {
	
	#
	# Is this an entry or a comment to an entry?
	#
	if ($this.replyto.depth == 0) {
		$this->lay_entrylite($.entry, "");
	} else {
		var string title = """Displaying a comment on the entry &ldquo;<a href="$this.entry.permalink_url">$this.entry.subject</a>&rdquo;.""";
		$this->lay_entrylite($.replyto, $title);
	}
	"""<div class="replyform">""";
	$this.form->print();
	"</div>";
}

function EntryPage::print_comments(Comment[] cs) {
	if (size $cs == 0) { return; }
	print """<div class="commentspacer">""";
	foreach var Comment c ($cs) {
		if ($c.full) {
			$this->print_comment($c);
		} else {
			$this->print_comment_partial($c);
		}
	}
	print """</div>""";
}

function Comment::print_linkbar() {
    var Link link;
    foreach var string k ($.link_keyseq) {
        $link = $this->get_link($k);
        print $link;
    }
}

function EntryPage::print_comment(Comment c) {

	var string poster = defined $c.poster ? $c.poster->as_string() : "$*text_poster_anonymous";
	if ($c.userpic) {
		$poster = $c.userpic->as_string() + $poster;
	}
	
	var string datetime = $c.time->date_format("%%HH%%:%%min%%, %%dd%%/%%mm%%/%%yyyy%%");
	var string dtstr = $datetime;
	if ($c.metadata{"poster_ip"}) { 
		$dtstr = $dtstr+" ("+$c.metadata{"poster_ip"}+")"; 
	}
	
	var string subject = ($c.subject == "") ? "" : $c.subject;
	if (defined $c.subject_icon) {
		$subject = """<img src="$c.subject_icon.url" alt="subject icon" />""" + $subject;
	}
	
	"""
	<div class="comment" id="$c.dom_id">
		<div class="comment-top" id="t$c.talkid">
			<div class="comment-datetime">$dtstr</div>
			<div class="ljuser">$poster</div>
		</div>
	""";
	
	if (size $c.link_keyseq > 0) {
		println """<div class="comment-tools">""";
		$c->print_linkbar();
		if ($.multiform_on) {
			$c->print_multiform_check();
		}
		println """</div>""";
	}
	
	println """<div class="commententry">""";
	println """<h2 class="comment-subject">$subject</h2>""";
	$c->print_text();
	println """</div>""";

	"""<div class="commenttalklinks"><a href="$c.permalink_url">$*text_permalink</a> """;
	
	if ($c.parent_url != "") { """<a href="$c.parent_url">parent</a> """; }
	$c->print_reply_link({"linktext" => "reply"});
	$c->print_reply_container({"class" => "commentqr"});
	
	"""</div>
	</div>
	<div id="c-reply-$c.talkid"></div>
	""";
	
	if ((size $c.replies) > 0) {
		if ($c.replies[0].full == false) {
			"""<div class="commentspacer">""";
			$this->print_comments($c.replies);
			"""</div>""";
		} else {
			$this->print_comments($c.replies);
		}
	}
}
function EntryPage::print_comment_partial(Comment c) {
	var string poster = defined $c.poster ? $c.poster->as_string() : "$*text_poster_anonymous";
	var string subj = $c.subject != "" ? $c.subject : $*text_nosubject;
	print """<div class="minicomment"><a href="$c.permalink_url">$subj</a> - $poster</div>\n""";
	$this->print_comments($c.replies);
}



function YearPage::lay_collapsed_month(YearMonth m) {
	if (not $m.has_entries) { return; }
	
	"""
	<tr class="c-item">
	<td class="c-expand"><a href='"""+$this->lay_build_url({".month" => string($m.month)})+"""#m-$m.month'>+</a></td>
	<td class="c-title"><a href="$m.url">"""+$m->month_format("%%month%%")+"""</a></td>
	</tr>
	""";

}

function YearPage::print_month(YearMonth m) {
	
	"""
	<tr><td colspan="2">
	<h2 class="yp-month-header"><a href="$m.url">"""+$m->month_format("%%month%%")+"""</a></h2>
	
	<table class="yp-month">""";
	   
	foreach var int d (weekdays()) {
		"""<th>$*lang_dayname_short[$d]</th>""";
	}
	"""</tr>""";
	foreach var YearWeek w ($m.weeks) {
		$w->print();
	}
	"""</table></td></tr>""";
}

function YearWeek::print() {
	"""<tr>""";
	if ($.pre_empty > 0) {
		foreach var int i (1..$.pre_empty) {
			"""<td class="yw-day-blank">&nbsp;</td>""";
		}
	}
	foreach var YearDay d ($.days) {
		if ($d.num_entries > 0) {
			"""
			<td class="yw-day-full">
				<span class="ymd">$d.day</span>
				<div class="yme"><a href="$d.url">$d.num_entries</a></div>
			</td>
			""";
		} else {
			"""
			<td class="yw-day-empty">
				<span class="ymd">$d.day</span>
				&nbsp;
			</td>
			""";
		}
	}
	if ($.post_empty > 0) {
		foreach var int i (1..$.post_empty) {
			"""<td class="yw-day-blank">&nbsp;</td>""";
		}
	}
	"""</tr>""";
}
function YearPage::print_body {
	"""<table class="central-table">""";
	foreach var YearMonth m ($.months) {
		if ($m.has_entries) {
			if ($.args{"month"} == string($m.month)) {
				$this->print_month($m);
			} else {
				$this->lay_collapsed_month($m);
			}
		}
	}
	"""</table>""";
}


function ReplyPage::print_body() {
	var EntryLite c = $.replyto;
	var string datetime;
	$datetime = $c.time->date_format("%%HH%%:%%min%%, %%dd%%/%%mm%%/%%yyyy%%");
	
	var string poster = defined $c.poster ? $c.poster->as_string() : "$*text_poster_anonymous";
		
	"""
	<div class="box">
		<div class="entry-header">
		<span class="ljuser">$poster</span>""";
	
	if ($c.subject != "") {
		print ": "+$c.subject;
	}
	"""
		</div>
		<div class="datetime">$datetime</div>
		<div class="entry">
		$c.text
		</div>
	</div>
	<div class="replybox">
	""";
	$.form->print();
	
	"""
	</div>
	""";
}


function MonthPage::print_body {
	
	"""<table class="central-table">""";
	#$.date->date_format($*lang_fmt_month_long)
	
	foreach var MonthDay d ($.days) {
		if ($d.has_entries) {
			"""
			<tr class="item">
				<td colspan="3"><h2 class="c-header"><a href="$d.url">"""+lang_ordinal($d.day)+"""</a></h2></td>
			</tr>
			""";
			
			foreach var Entry e ($d.entries) {
				$this->lay_collapsed_entry($e);
			}
		}
	}
	"""</table>""";
}

function Page::print() {

"""
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN"
		"http://www.w3.org/TR/xhtml1/DTD/xhtml1-loose.dtd">
	   <html xmlns="http://www.w3.org/1999/xhtml" lang="en" xml:lang="en">

<head>
<title>"""+$this->title()+"""</title>
"""; 
	$this->print_head(); 
"""
<link rel="stylesheet" type="text/css" href="$.stylesheet_url" />
""";
	if ($*custom_favicon != "") {
		"""<link rel="shortcut icon" href="$*custom_favicon" />""";
	}
"""
</head>
<body class="$.journal.username-$.view">
	<div id="side">
	""";
	
	$this->lay_side_boxes();
	
	print_footer();
	"""
	</div>
	
	<div id="central">
	""";
	
	$this->print_body(); 
	
	
	"""
	</div>
</body>
</html>
""";
}